Drag and Drop not working in maxi-patch

JammyBStard · Post by **JammyBStard** » Sat Sep 01, 2007 12:05 pm

running Maxi-patch audio only version (havn't tried the AV version), I can't drag and drop folders into either the file menue areas or the Batch waveform process areas.

Any help appriciated

System:
Pinky Stuff:
-----Hp nx7400 lappy
-----Windows Vista Business (I know, Bad Idea)
-----Presonus Firbox
-----Berhinger BEAT-800 (BPM counter, but it has two built in pre-amps)
-----ebay 8way Studio loom - RCA (phono) to 3.5mm mono Jack
Oldscool Stuff:
-----Vestax PDXa1 decks (A design classic)
-----Vestax PCV-003 Mixer
-----Stanton 500 cart and needles

upasaka · Post by **upasaka** » Sun Sep 02, 2007 9:26 am

not terribly helpful I know, but I've had a similar problem under Vista. strange thing is, it worked fine at first! but then for some reason it died (OS patch maybe??), and nothing I've tried seems to restore it. for now I resorted to editing the audio_folders file by hand

JammyBStard · Post by **JammyBStard** » Sun Sep 02, 2007 2:03 pm

How do you go about editing the audio_folders file by hand?

I have two problems actually,
1: I cant drag and drop as above
2: In the Pinky Pluggo I dont get any waveforms in the 2 waveform displays. this might be true of the Maxi-patch too but i havent been able to drag any tnes in to try!

Would appriciate a response from the Pinkstah on these issues!

Cheers

Post by **dlpinkstah** » Mon Sep 03, 2007 5:22 am

This is probably a Windoze Vista issue, as our drag-n-drop and file waveform stuff is very much working under XP, and of course OSX. So shame on you for supporting EVIL MICROSOFT by buying Vista!!

JammyBStard · Post by **JammyBStard** » Mon Sep 03, 2007 8:14 pm

Thats all fair enough Pinksta; I new well enough when I paid my money that you only stated supportt for XP, And I was ready to role back my new machine to XP if it came to it.
But to tell the truth, I was ready to hate vista when I ordered it, but once I turned off all the visual fluff and other memory draining crap that comes as standard, I actually like it, It's ran solidly since I first turned it on. It is yet to crash! (I'm sure it'll wait until I'm playing a gig to hundereds)

Anyway, what I'm digging at is; how long do you think before you have to bite the bullet and make it work fully in Vista? i guess your going to have to soon in the not so distant future, Most cheap laptop bundles come with it already.

Post by **dlpinkstah** » Tue Sep 04, 2007 3:01 am

Eventually, yes. But it may be that the polar ice caps completely melt first...

For maximum Ms Pinky satisfaction, you're better off going back to XP for now, if you can.

upasaka · Post by **upasaka** » Tue Sep 04, 2007 5:34 am

in my defence, I switched to Vista (for free) cuz I needed the better tablet pc support...

Sirs, I have hacked up a workaround for the drag and drop problem -- a simple VBScript (again, sorry) that will recurse the starting directory/folder you tell it to (with a hardcoded default value), and produce the correctly formatted audio_folders file (which of course is in the root directory of Maxi-Patch).

So if you want it, keep reading. No warranties!

1. copy the text below and save as somefile.vbs; to run just double click
2. edit the file and change START_DIR to be the default file path to where your audio content is kept (assuming you do that *shrug*)
3. edit the file and change AUDIO_FOLDERS to be the target file path to the audio_folders file that Maxi-Patch uses

If you run it then start Maxi-Patch, your recursively parsed directory list should be there. This was I can at least use the software okay.

-- ms pinky audio_folders updater hack --

Code: Select all

Option Explicit

Const START_DIR = "C:\audio\_DIRECT" ' path to start search & replace; use "." for CWD
Const ALLOWED_SUFFIXES = "mp3,wav,aac"
Const AUDIO_FOLDERS = "C:\audio\Maxi-Patch_AO\audio_folders"

'-- File I/O
Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8

Dim oFSO, sCWD, aAllowedSuffixes, sExec, oaudio_folders
Dim iLine, strOut
'- Get FileSystemObject
Set oFSO = CreateObject("Scripting.FileSystemObject")
'- Open audio_folders for write
Set oaudio_folders = oFSO.OpenTextFile(AUDIO_FOLDERS, ForWriting, True)

Dim regex
Set regex = New RegExp

iLine = 1

Dim strStart
' Get target directory
strStart = InputBox("Target location of audio_folders:","ms pinky haXor",START_DIR)
sCWD = oFSO.GetAbsolutePathName(strStart)

'- Build allowed suffixes array
aAllowedSuffixes = Split(ALLOWED_SUFFIXES,",")

'- Perform the recursive update
Call RecursiveUpdate(sCWD)

'- Transform to posix style
regex.Global = True
regex.Pattern = "\\"
strOut = regex.Replace(strOut,"/")
Set regex = Nothing

oaudio_folders.Write strOut
oaudio_folders.Close()
Set oFSO = Nothing

wscript.quit

'-- End

Sub RecursiveUpdate(ByVal sStartFolder)
	On Error Resume Next
	Dim oFolder, oSubs, oFiles
	Dim vFile, vFolder, vSuffix
	Dim bMatch
	bMatch = False

	'- Connect to the start folder
	Set oFolder = oFSO.GetFolder(sStartFolder)

	'- Check the immediate folder
	Set oFiles = oFolder.Files
	For Each vFile In oFiles
		For Each vSuffix In aAllowedSuffixes
			If LCase(Right(vFile.Name,Len(vSuffix)+1)) = LCase("."&vSuffix) Then ' suffix match found
				'- the pinky only wants wrapping quotes if the string contains whitespace...
				regex.Pattern = " "
				If regex.Test(sStartFolder) Then
					strOut = strOut & iLine & ", """ & sStartFolder & """;" & vbCrLf
				Else
					strOut = strOut & iLine & ", " & sStartFolder & ";" & vbCrLf
				End If
				iLine = iLine + 1
'				wscript.echo "Include: " & sStartFolder
				bMatch = True
				Exit For	
			End If
		Next
		If bMatch Then Exit For
	Next

	'- Now recurse into sub folders
	Set oSubs = oFolder.SubFolders
	For Each vFolder In oSubs
		Call RecursiveUpdate(sStartFolder&"\"&vFolder.Name)
	Next

	Set oSubs = Nothing
	Set oFiles = Nothing
	Set oFolder = Nothing
End Sub

Post by **dlpinkstah** » Tue Sep 04, 2007 7:36 pm

Totally cool!!

Big up to UPasaka!

As some of you may have noticed the contents of the audio files menu are read from the file called "audio_folders" which is in the same directory with the Maxi-Patch application. It's a very simple structure: each line contains it's index number and the pathname of the folder you want displayed, followed by a semicolon. Same is true for the "QT_folders" file stores the contents of the Quick-Time movie folders menu.

upasaka · Post by **upasaka** » Thu Sep 06, 2007 12:53 am

ahhh cool! I was a bit worried I'd offend by posting that...

would most humbly love to see an update that handles Vista though, just to get the full magic of ms pinky back

JammyBStard · Post by **JammyBStard** » Thu Sep 06, 2007 6:02 pm

Hi Upsaka
i tried the following script:

Option Explicit

Const START_DIR = "C:\File_Archive\Archive_-_Record Box" ' path to start search & replace; use "." for CWD
Const ALLOWED_SUFFIXES = "mp3,wav,aac"
Const AUDIO_FOLDERS = "C:\audio\Maxi-Patch_AO\audio_folders"

'-- File I/O
Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8

Dim oFSO, sCWD, aAllowedSuffixes, sExec, oaudio_folders
Dim iLine, strOut
'- Get FileSystemObject
Set oFSO = CreateObject("Scripting.FileSystemObject")
'- Open audio_folders for write
Set oaudio_folders = oFSO.OpenTextFile(AUDIO_FOLDERS, ForWriting, True)

Dim regex
Set regex = New RegExp

iLine = 1

Dim strStart
' Get target directory
strStart = InputBox("Target location of audio_folders:","ms pinky haXor",START_DIR)
sCWD = oFSO.GetAbsolutePathName(strStart)

'- Build allowed suffixes array
aAllowedSuffixes = Split(ALLOWED_SUFFIXES,",")

'- Perform the recursive update
Call RecursiveUpdate(sCWD)

'- Transform to posix style
regex.Global = True
regex.Pattern = "\\"
strOut = regex.Replace(strOut,"/")
Set regex = Nothing

oaudio_folders.Write strOut
oaudio_folders.Close()
Set oFSO = Nothing

wscript.quit

'-- End

Sub RecursiveUpdate(ByVal sStartFolder)
On Error Resume Next
Dim oFolder, oSubs, oFiles
Dim vFile, vFolder, vSuffix
Dim bMatch
bMatch = False

'- Connect to the start folder
Set oFolder = oFSO.GetFolder(sStartFolder)

'- Check the immediate folder
Set oFiles = oFolder.Files
For Each vFile In oFiles
For Each vSuffix In aAllowedSuffixes
If LCase(Right(vFile.Name,Len(vSuffix)+1)) = LCase("."&vSuffix) Then ' suffix match found
'- the pinky only wants wrapping quotes if the string contains whitespace...
regex.Pattern = " "
If regex.Test(sStartFolder) Then
strOut = strOut & iLine & ", """ & sStartFolder & """;" & vbCrLf
Else
strOut = strOut & iLine & ", " & sStartFolder & ";" & vbCrLf
End If
iLine = iLine + 1
' wscript.echo "Include: " & sStartFolder
bMatch = True
Exit For
End If
Next
If bMatch Then Exit For
Next

'- Now recurse into sub folders
Set oSubs = oFolder.SubFolders
For Each vFolder In oSubs
Call RecursiveUpdate(sStartFolder&"\"&vFolder.Name)
Next

Set oSubs = Nothing
Set oFiles = Nothing
Set oFolder = Nothing
End Sub

And got the following error:

[/img]

What am I doing wrong man?

Ta

upasaka · Post by **upasaka** » Fri Sep 07, 2007 4:41 am

JammyBStard,
You need to change the AUDIO_FOLDERS constant to point to wherever your Maxi-Patch install directory is; ie,
Const AUDIO_FOLDERS = "C:\audio\Maxi-Patch_AO\audio_folders"

So find Maxi-Patch's file path, update the script, and it should work.

JammyBStard · Post by **JammyBStard** » Sat Sep 08, 2007 11:23 am

Nice one Upsaka; think I'm there now.

No waveforms in MAxi-patch either though. Do you see the same fault with your Vista instalation? It's a shame cos its the only issue left now!

upasaka · Post by **upasaka** » Sun Sep 09, 2007 9:35 am

Actually the waveforms work fine for me. You realise you need to tell Maxi-Patch to generate them? Hold shift then double-click in the waveform area...

no_half_steppin · Post by **no_half_steppin** » Fri Oct 12, 2007 8:02 pm

Hi Upsaka, thanks again for posting this solution.

But I don't know how or where to save the script or how to save it period.

I found ( I think) the audio file but I can't seem to open it, when I look at what type of file it is, it just says file.

Any help would be appreciated. Thanks.